home *** CD-ROM | disk | FTP | other *** search
/ PC World 2006 July & August / PCWorld_2006-07-08_cd.bin / komunikace / apache / apache_2[1].2.2-win32-x86-no_ssl.msi / Data1.cab / _BC23A1D68DE1DF2C724D04611E104BB8 (.txt) < prev    next >
LaTeX Document  |  2006-04-21  |  11KB  |  294 lines
  1. <?xml version="1.0"?>
  2.  Copyright 2003-2005 The Apache Software Foundation or its licensors, as
  3.  applicable.
  4.  Licensed under the Apache License, Version 2.0 (the "License");
  5.  you may not use this file except in compliance with the License.
  6.  You may obtain a copy of the License at
  7.      http://www.apache.org/licenses/LICENSE-2.0
  8.  Unless required by applicable law or agreed to in writing, software
  9.  distributed under the License is distributed on an "AS IS" BASIS,
  10.  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11.  See the License for the specific language governing permissions and
  12.  limitations under the License.
  13. <xsl:stylesheet version="1.0"
  14.               xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  15.                   xmlns="http://www.w3.org/1999/xhtml">
  16. <!-- ==================================================================== -->
  17. <!-- <modulesynopsis>                                                     -->
  18. <!-- ==================================================================== -->
  19. <xsl:template match="modulesynopsis">
  20. <xsl:text>\section{</xsl:text>
  21. <xsl:choose>
  22.   <xsl:when test="../status='Core'">
  23.     <xsl:value-of select="$message[@id='apachecore']" />
  24.   </xsl:when>
  25.   <xsl:when test=".='mpm_common'">
  26.     <xsl:value-of select="$message[@id='apachempmcommon']" />
  27.   </xsl:when>
  28.   <xsl:when test="../status='MPM'">
  29.     <xsl:value-of select="$message[@id='apachempm']" />
  30.     <xsl:text> </xsl:text>
  31.     <xsl:apply-templates select="name"/>
  32.   </xsl:when>
  33.   <xsl:otherwise>
  34.     <xsl:value-of select="$message[@id='apachemodule']" />
  35.     <xsl:text> </xsl:text>
  36.     <xsl:apply-templates select="name"/>
  37.   </xsl:otherwise>
  38. </xsl:choose>
  39. <xsl:text>}\label{</xsl:text>
  40. <xsl:value-of select="concat('/mod/',name)"/>
  41. <xsl:text>}\hypertarget{</xsl:text>
  42. <xsl:value-of select="concat('/mod/',name)"/>
  43. <xsl:text>}{}</xsl:text>
  44. <xsl:text>
  45. \begin{tabular}{lp{.75\linewidth}}
  46. \hline
  47. </xsl:text>
  48. <xsl:value-of select="$message[@id='description']" />
  49. <xsl:text>: &</xsl:text> 
  50. <xsl:apply-templates select="description" />
  51. <xsl:text>\\
  52. </xsl:text>
  53. <xsl:value-of select="$message[@id='status']" />
  54. <xsl:text>: &</xsl:text>
  55. <xsl:value-of select="status" />
  56. <xsl:text>\\
  57. </xsl:text>
  58. <xsl:if test="identifier">
  59. <xsl:value-of select="$message[@id='moduleidentifier']" />
  60. <xsl:text>: &</xsl:text>
  61. <xsl:apply-templates select="identifier" />
  62. <xsl:text>\\
  63. </xsl:text>
  64. </xsl:if>
  65. <xsl:if test="sourcefile">
  66. <xsl:value-of select="$message[@id='sourcefile']" />
  67. <xsl:text>: &</xsl:text>
  68. <xsl:apply-templates select="sourcefile" />
  69. <xsl:text>\\
  70. </xsl:text>
  71. </xsl:if>
  72. <xsl:if test="compatibility">
  73. <xsl:value-of select="$message[@id='compatibility']" />
  74. <xsl:text>: &</xsl:text>
  75. <xsl:apply-templates select="compatibility" />
  76. <xsl:text> \\
  77. </xsl:text>
  78. </xsl:if>
  79. <xsl:text>\hline \end{tabular}
  80. </xsl:text>
  81.     <!-- Summary of module features/usage (1 to 3 paragraphs, -->
  82.     <!-- optional)                                            -->
  83.     <xsl:if test="summary">
  84.       <xsl:text>\subsection*{</xsl:text>
  85.       <xsl:value-of select="$message[@id='summary']" />
  86.       <xsl:text>}
  87. </xsl:text>
  88.       <xsl:apply-templates select="summary" />
  89.      </xsl:if>
  90.      <xsl:text>
  91. \smallskip\textbf{</xsl:text>
  92.      <xsl:value-of select="$message[@id='directives']" />
  93.      <xsl:text>}
  94. </xsl:text>
  95.      <xsl:choose>
  96.      <xsl:when test="directivesynopsis">
  97.        <xsl:text>\begin{itemize}</xsl:text>
  98.        <xsl:for-each select="directivesynopsis">
  99.          <xsl:sort select="name" />
  100.          <xsl:text>\item </xsl:text>
  101.          <xsl:if test="@type='section'">
  102.            <xsl:text>\textless{}</xsl:text>
  103.          </xsl:if>
  104.          <xsl:apply-templates select="name" mode="simple"/>
  105.          <xsl:if test="@type='section'">
  106.            <xsl:text>\textgreater{}</xsl:text>
  107.          </xsl:if>
  108.          <xsl:if test="@location">
  109.            <xsl:variable name="lowerlocation"
  110.             select="translate(@location, $uppercase, $lowercase)" />
  111.            <xsl:text> (p.\ \pageref{/mod/</xsl:text>
  112.            <xsl:value-of select="concat(translate(@location,$uppercase,$lowercase),':',translate(name,$uppercase,$lowercase))"/>
  113.            <xsl:text>}) </xsl:text>
  114.          </xsl:if>
  115.          <xsl:text>
  116. </xsl:text>
  117.        </xsl:for-each>
  118.        <xsl:text>\end{itemize}
  119. </xsl:text>
  120.      </xsl:when>
  121.      <xsl:otherwise>
  122.        <xsl:value-of select="$message[@id='nodirectives']" />
  123.      <xsl:text>
  124. </xsl:text>
  125.      </xsl:otherwise>
  126.      </xsl:choose>
  127.      <xsl:text>
  128. </xsl:text>
  129. <xsl:call-template name="seealso"/>
  130.      <!-- Sections of documentation about the module as a whole -->
  131.        <xsl:apply-templates select="section" />
  132.      <!-- Directive documentation -->
  133.        <xsl:apply-templates select="directivesynopsis">
  134.          <xsl:sort select="name" />
  135.        </xsl:apply-templates>
  136. </xsl:template>
  137. <!-- /modulesynopsis -->
  138. <!-- ==================================================================== -->
  139. <!-- Directivesynopsis                                                    -->
  140. <!-- ==================================================================== -->
  141. <xsl:template match="directivesynopsis/name" mode="simple" name="simpledirname">
  142. <xsl:if test="@type='section'"><xsl:text>\textless{}</xsl:text></xsl:if>
  143. <xsl:apply-templates/>
  144. <xsl:if test="@type='section'"><xsl:text>\textgreater{}</xsl:text></xsl:if>
  145. </xsl:template>
  146. <xsl:template match="directivesynopsis/name">
  147. <xsl:text>\subsection*{</xsl:text>
  148. <xsl:call-template name="simpledirname"/>
  149.   <xsl:choose>
  150.   <xsl:when test="$message[@id='directive']/@replace-space-with">
  151.     <xsl:value-of select="$message[@id='directive']/@replace-space-with"/>
  152.   </xsl:when>
  153.   <xsl:otherwise>
  154.     <xsl:text> </xsl:text>
  155.   </xsl:otherwise>
  156.   </xsl:choose>
  157. <xsl:value-of select="$message[@id='directive']" />
  158. <xsl:text>}\label{</xsl:text>
  159. <xsl:value-of select="concat('/mod/', //modulesynopsis/name, ':', translate(., $uppercase, $lowercase))"/>
  160. <xsl:text>}\hypertarget{</xsl:text>
  161. <xsl:value-of select="concat('/mod/', //modulesynopsis/name, ':', translate(., $uppercase, $lowercase))"/>
  162. <xsl:text>}{}</xsl:text>
  163. </xsl:template>
  164. <xsl:template match="directivesynopsis">
  165. <xsl:if test="not(@location)">
  166.   <xsl:apply-templates select="name"/>
  167.   <!-- Directive header -->
  168.   <xsl:text>
  169. \begin{tabular}{lp{.8\linewidth}}
  170. \hline
  171. </xsl:text>
  172. <xsl:value-of select="$message[@id='description']" />
  173. <xsl:text>: & </xsl:text>
  174. <xsl:apply-templates select="description" />
  175. <xsl:text>\\
  176. </xsl:text>
  177. <xsl:value-of select="$message[@id='syntax']" />
  178. <xsl:text>: & {\ttfamily </xsl:text>
  179. <xsl:apply-templates select="syntax" />
  180. <xsl:text>}\\
  181. </xsl:text>
  182. <xsl:if test="default">
  183. <xsl:value-of select="$message[@id='default']" />
  184. <xsl:text>: & {\ttfamily </xsl:text>
  185. <xsl:apply-templates select="default" />
  186. <xsl:text>} \\
  187. </xsl:text>
  188. </xsl:if>
  189. <xsl:value-of select="$message[@id='context']" />
  190. <xsl:text>: &</xsl:text>
  191. <xsl:apply-templates select="contextlist" />
  192. <xsl:text> \\
  193. </xsl:text>
  194. <xsl:if test="override">
  195. <xsl:value-of select="$message[@id='override']"/>
  196. <xsl:text>: &</xsl:text>
  197. <xsl:apply-templates select="override" />
  198. <xsl:text> \\
  199. </xsl:text>
  200. </xsl:if>
  201. <xsl:value-of select="$message[@id='status']" />
  202. <xsl:text>: &</xsl:text>
  203. <xsl:value-of select="../status" />
  204. <xsl:text> \\
  205. </xsl:text>
  206. <xsl:value-of select="$message[@id='module']" />
  207. <xsl:text>: &</xsl:text>
  208. <xsl:choose>
  209. <xsl:when test="modulelist">
  210.   <xsl:apply-templates select="modulelist" />
  211. </xsl:when>
  212. <xsl:otherwise>
  213.   <xsl:apply-templates select="../name" />
  214. </xsl:otherwise>
  215. </xsl:choose>
  216. <xsl:text> \\
  217. </xsl:text>
  218. <xsl:if test="compatibility">
  219. <xsl:value-of select="$message[@id='compatibility']" />
  220. <xsl:text>: &</xsl:text>
  221. <xsl:apply-templates select="compatibility" />
  222. <xsl:text> \\
  223. </xsl:text>
  224. </xsl:if>
  225. <xsl:text>\hline
  226. \end{tabular}
  227. </xsl:text>
  228. <xsl:apply-templates select="usage" />
  229. <xsl:call-template name="seealso"/>
  230. </xsl:if> <!-- /not(@location) -->
  231. </xsl:template>
  232. <!-- /directivesynopsis -->
  233. <!-- ==================================================================== -->
  234. <!-- <contextlist>                                                        -->
  235. <!-- ==================================================================== -->
  236. <xsl:template match="contextlist">
  237. <xsl:apply-templates select="context" />
  238. </xsl:template>
  239. <!-- /contextlist -->
  240. <!-- ==================================================================== -->
  241. <!-- <context>                                                            -->
  242. <!-- Each entry is separeted with a comma                                 -->
  243. <!-- ==================================================================== -->
  244. <xsl:template match="context">
  245. <xsl:choose>
  246. <xsl:when test="normalize-space(.) = 'server config'">
  247.     <xsl:value-of select="$message[@id='serverconfig']" />
  248. </xsl:when>
  249. <xsl:when test="normalize-space(.) = 'virtual host'">
  250.     <xsl:value-of select="$message[@id='virtualhost']" />
  251. </xsl:when>
  252. <xsl:when test="normalize-space(.) = 'directory'">
  253.     <xsl:value-of select="$message[@id='directory']" />
  254. </xsl:when>
  255. <xsl:when test="normalize-space(.) = '.htaccess'">
  256.     <xsl:value-of select="$message[@id='htaccess']" />
  257. </xsl:when>
  258. <xsl:otherwise> <!-- error -->
  259.     <xsl:message terminate="yes">
  260.         unknown context: <xsl:value-of select="." />
  261.     </xsl:message>
  262. </xsl:otherwise>
  263. </xsl:choose>
  264. <xsl:if test="position() != last()">
  265.     <xsl:text>, </xsl:text>
  266. </xsl:if>
  267. </xsl:template>
  268. <!-- /context -->
  269. <!-- ==================================================================== -->
  270. <!-- <modulelist>                                                         -->
  271. <!-- ==================================================================== -->
  272. <xsl:template match="modulelist">
  273. <xsl:for-each select="module">
  274.     <xsl:call-template name="module" />
  275.     <xsl:if test="position() != last()">
  276.         <xsl:text>, </xsl:text>
  277.     </xsl:if>
  278. </xsl:for-each>
  279. </xsl:template>
  280. <!-- /modulelist -->
  281. <!-- ==================================================================== -->
  282. <!-- modulesynopsis/compatibility                                         -->
  283. <!-- ==================================================================== -->
  284. <xsl:template match="modulesynopsis/compatibility">
  285. <xsl:apply-templates />
  286. </xsl:template>
  287. <!-- ==================================================================== -->
  288. <!-- directivesynopsis/compatibility                                      -->
  289. <!-- ==================================================================== -->
  290. <xsl:template match="directivesynopsis/compatibility">
  291. <xsl:apply-templates />
  292. </xsl:template>
  293. </xsl:stylesheet>
  294.